World: r4wp

I don't rememeber who did the neon effect, but here it is.

font-C: make face/font [style: [ bold ] size: 64]
neon: "REBOL BAR"
coord: 30x15
inc: 0.25.25
draw-block: compose [
	line-join round font font-c

 pen (inc * 1 + 255.0.0.230) line-width 11 text vectorial coord neon

 pen (inc * 2 + 255.0.0.205) line-width 9 text vectorial coord neon

 pen (inc * 3 + 255.0.0.180) line-width 8 text vectorial coord neon

 pen (inc * 4 + 255.0.0.155) line-width 7 text vectorial coord neon

 pen (inc * 5 + 255.0.0.130) line-width 6 text vectorial coord neon

 pen (inc * 6 + 255.0.0.105) line-width 5 text vectorial coord neon

 pen (inc * 7 + 255.0.0.80) line-width 4 text vectorial coord neon

 pen (inc * 8 + 255.0.0.55) line-width 3 text vectorial coord neon

 pen (inc * 9 + 255.0.0.30) line-width 2 text vectorial coord neon

 pen (inc * 10 + 255.0.0.5) line-width 1 text vectorial coord neon
]

view/title layout [ box black 450x200 effect [ draw draw-block ] 
] "NEON"

Thank's Geomol, Steeve, these are very good examples of DRAW.

Great examples!

Steeve, I copied and pasted this on the Mac, but I only see a black 
box in a grey window with title "NEON"

Vectorial texts only works on Windows IIRC

ok that explains!

MaxV, it works well in the current version.

Done with linux, see: http://rebol2.blogspot.it/2012/12/rebol-draw-on-linux.html

both examples!

Which REBOL version?

2.7.8 Works better for me, but Neon gives a black window

Did you use the code on the blog post? It's different form the one 
here, I added the font support for Linux: you have to ad the path 
where are the font. Read carefull the post.

Cool, that fixes it

By the way, your first example starts with garbled HTML

Yes, I noticed it. Just corrected.

Thanks

Isn't that interesting?
>> ? #a
#a is an issue

>> copy/part next #aaaa 2
== #aa ;<-- issue!

>> pick #aaa 2
== #"a"  ;<-- char!

Why the last one is not an issue?

in R2, issue! is string!, So PICK gets char!. COPY retain the datatype, 
which is issue here.

in R3, you cannot COPY and PICK a issue!, because it's not string 
any more.

(Pardon the level-up in the lesson.)

That's not necessarily the case for R3, it's just the case *now*. 
COPY and PICK are just actions, which could easily be defined for 
the issue! type. You could get most of the R2-like behavior for issues 
in R3 by emulating the way tuples pretend to be series when they're 
really not.


The type classes in Rebol aren't like base classes in OOP languages, 
they are more like behavioral conventions, and those conventions 
are more like Go interfaces than anything OOP. Something is series-like 
to the extent that it behaves like a series is supposed to behave. 
But the acrions that are defined for series types are in some cases 
also defined for other types as well, and the corresponding behavior 
for those types can be similar enough to that of series to allow 
both series and, say, tuples, to be operated on by the same code. 
All that matters is how it seems to act from the outside, not what 
it really is.

We've been making this even more the case in R3 and R2 lately, such 
as when we allowed SELECT to be used on objects (and maps in R3), 
since that is a function that is used to make series act like objects. 
Or when we allowed APPEND to work on objects and maps in R3, since 
there was a corresponding behavior that could be defined for those 
types, but didn't do the same for INSERT because its positional return 
value has no corresponding concept for object-like types.

For issues, we could have COPY return another issue of the same spelling, 
COPY/part return another issue spelled like that portion of the original 
(only integer part values, not offset positions because words don't 
have positions), and PICK return a character just as if the issue 
was a character container like strings are. We would have to avoid 
the positional functions, and the modifying functions could retern 
a different version the way that they do for the similarly immutable 
tuples, but the rest could be emulated as-is.

So I have a block
	account: make object! [
	  name: "James"
	  balance: $100
	  ss-number: #1234-XX-4321
	  deposit:  func [amount] [balance: balance + amount]
	  withdraw: func [amount] [balance: balance - amount]
	]

and I save it

	save %account-object account

then I read it back in

	new-account: load %account-object

account is an object, whilst new-account is a block.


My question is, how do I load the object into new-account as an object? 
So I end up with another object, not a block

Have you tried

new-account: do load %account-object

Ah, of course, the missing 'do' word to make it evaluate! Thanks 
GrahamC.

btw - do might be unsecure, e.g. with CGI code. Maybe 'construct 
would do the trick too, without evaluating the stuff?

I see what you mean. I just read the function summary for 'construct'. 
My objects are encrypted before they get saved anywhere. Thanks for 
the tip Pekr.

you can also use SAVE/ALL to save in serialized form:
>> o: context [a: 1] save/all %file.r o p: load %file.r type? p
== object!

Very usefull. Just what I like about Rebol Thanks Endo.

the most secure method is to SAVE/ALL AND CONSTRUCT.


also, btw, using MOLD/ALL can save a lot of ram because things like 
hash! and objects! do not get double allocated.  on big datasets 
like I'm  using it means saving 100MB RAM on app startup . :-)


just be carefull with save/all & mold/all   they can corrupt some 
data types just like when /ALL  isn't used.  it does allow much more, 
but it still can create some un-reloadable issues... always test 
it with your current data structures before blindly adopting it.

Yes, here is an example:
>> save/all %file.txt o context [a: self]
>> load %file.txt
** Syntax Error: Missing ] at end-of-script

file.txt file is:
#[object! [
    a: #[object! [...]   ;<---
]]

cyclical data cannot be serialized by any of the internal tools.

though one can write his own mold function which handles the above 
(I once did so).   its just tedious to support all types (there are 
so many)

Caelum, SAVE/all and MOLD/all will have trouble saving your example 
object in a restorable state. The problem is those functions defined 
in the object, and bound to its fields. Those bindings won't be restored. 
For data that has to be saved and restored safely you're better off 
with having functions that operate on objects, rather than objects 
with functions in them. The "safely" part actually refers to not 
executing code, and you have to execute code to create functions. 
It's better to put your code in one file which you can protect, and 
your data in another file which you can be more wary of.

Rebol isn't class-based. In class-based languages, that separation 
of code and data happens automatically - code is class definitions, 
data is instance creation. In Rebol, if you need to keep your code 
and data separate you have to do it yourself.

In this case, you keep your code and data separate because code is 
best saved with MOLD and reconstructed with DO, but data of types 
that don't have a normal literal form (but aren't affected by binding) 
are often better saved with MOLD/all and restored with LOAD. The 
main thing is that we don't have a literal syntax to declare word 
bindings; instead, we have a way to construct them with code. Same 
goes for cyclic or DAG structures that aren't strictly nested. So, 
if you need to create such things, you need to run code. And you 
need to keep your untrustworthy data that you can't safely DO separate 
from that code.

Thanks BrianH. I am aware of the need to "keep your untrustworthy 
data that you can't safely DO separate from that code."


I am creating a small Rebol server capable of communicating with 
clients, using RSA key exchange and the blowfish algorithm, both 
of which work to reasonably high encryption levels in Rebol, 4096 
for RSA and 512 for Blowfish (yes I know the effective upper limit 
for Blowfish is 448 bits, but that is good enough for my purposes).


I want to save the RSA key as a block so it can be loaded back into 
the program and used again, hence my question. It will be encrypted, 
wherever it gets saved, so there will be no chance of it being messed 
with.


Actually, I am writing a much simpler version of Rebol Services, 
since I could not get that to work and my ability to code in Rebol 
was not sufficiently developed yet to see how to get it working.


I am in a steep learning curve right now with Rebol and the time 
I am investing is starting to pay off. Thanks for the information 
about keeping code and data separate. It's always good to be reminded 
of 'obvious' truths.

Francis, if you search through the Qtask source, you will find a 
448 encryptor writte in JS that runs in the browser, you might enjoy 
how we did it.

So I have 

mailbox: open [
    scheme: 'pop
    user: "[user-:-domain-:-org]"
    pass: "password"
    host: "mail.domain.org"
]


and I am getting my email as expected. Two questions. Is my password 
being encrypted by Rebol when it communicates with my mail server? 
How do I know?

trace/net on
and then see the exchange

From memory, pop supports apop.

If you want encryption, use pops or spop

Replacing pop with apop, spop or pops in mailbox all produce the 
same error:
    ** Access Error: Invalid port spec: scheme apop

See here http://stackoverflow.com/questions/1128826/downloading-mail-from-hotmail

So I have a question about RSA encryption. When I run the following 
code:

  rsa-key: rsa-make-key
  rsa-generate-key rsa-key 1024 3

  crypt-key: copy/part checksum/secure mold now/precise 16
  print crypt-key

  crypt-key: rsa-encrypt rsa-key crypt-key
  print crypt-key

  crypt-key: rsa-encrypt/private/decrypt rsa-key crypt-key
  print crypt-key


it runs perfectly, encrypts the crypt-key and then decrypts it sucessfully.


As you probably know, the purpose of the RSA algorithm is to allow 
someone else to encrypt data that only you can decrypt using your 
private key. I tried this with a different public key using the following 
code:

  rsa-key1: rsa-make-key
  rsa-generate-key rsa-key1 1024 3

  rsa-key2: rsa-make-key
  rsa-key2/n: rsa-key1/n

  crypt-key: copy/part checksum/secure mold now/precise 16
  print crypt-key

  crypt-key: rsa-encrypt rsa-key2 crypt-key
  print crypt-key

  crypt-key: rsa-encrypt/private/decrypt rsa-key2 crypt-key
  print crypt-key


So I put the public key from rsa-key1 into another object, rsa-key2 
and tried using it to encrypt the data and get the following error.

	#{DD44AC1810E9A7020FAD72A7CFA54100}
	Segmentation fault


How do I get the public key from the first object into the second 
object so that it can be used to encrypt data?

caelum, I corrected your non-working exaple:

;key1 - contains public and private keys
rsa-key1: rsa-make-key
rsa-generate-key rsa-key1 1024 3

;key2 - contains only public key
rsa-key2: rsa-make-key
rsa-key2/e: 3
rsa-key2/n: rsa-key1/n

;data to ecrypt encrypt 
data: copy/part checksum/secure mold now/precise 16

;encrypt data using the key2 (with pub key only)
crypt-key: rsa-encrypt rsa-key2 data


;decrypt data(that have been encrypted using key2) using the key1(needs 
to contain private key)
data2: rsa-encrypt/private/decrypt rsa-key1 crypt-key

either equal? data data2 [
	print "decrypted data match the original - decription passed"
][

 print "decrypted data differs from the original - decryption failed"
]

the problem was you forgot to set the generator value (key/e) when 
makeing rsa-key2

and also you tried to decrypt the data using rsa-key2 which doesn't 
contain the private key

Got it! Thanks Cyphre, much appreciated.