[REBOL] progress-bars once again ...
From: petr::krenzelok::trz::cz at: 20-Oct-2000 6:47
So, as our new mailserver doesn't allow attachements, here's my example
once again ....
Cheers,
-pekr-
REBOL [
Title: "Progress bars ..."
Author: "Petr Krenzelok"
Email: [petr--krenzelok--trz--cz]
Date: 19-Oct-2000
Comment: {Just played a little bit with progress bars. The bar object
is shared,
as it's with all rebol nested object by default (I now know
it thank's
to Elan's book - thanks Elan :-). So if you want to have
various styles,
save the bar object first. Don't use default one!
I think last progress bar is showing we can have even
animated ones :-)
Anyone for small bubbles coming from bottom to up? ;-)
You also need carlwaves.jpg and progr3 uses two images -
substitute any
ones, but set effect to none, as it seems to try to fit your
image and
the result is unpleasant black&white 'something' ...
}
]
saved-bar: make system/view/vid/vid-styles/progress/bar []
;print mold saved-bar
styly: stylize [
txt: text bold font [shadow: none]
progr1: progress with [
color: none
bar: make saved-bar []
bar/color: none
bar/effect: [gradmul 0x1 255.100.100]
]
progr2: progress with [
color: none
bar: make saved-bar []
bar/color: none
bar/effect: [gradient 0x1 0.0.250]
]
progr3: progress with [
image: load %polarcap.jpg
effect: none
bar: make saved-bar []
bar/image: load %rice.jpg
bar/effect: [tile]
]
progr4: progress with [
color: none
bar: make saved-bar []
bar/color: none
bar/effect: [gradient 1x0 0.0.250]
bar/rate: 1
bar/text: true
bar/feel/engage: func [f a e][
either f/text [f/effect: [gradient -1x0
0.0.250] f/text: false show f
][f/effect: [gradient 1x0 0.0.250] f/text: true
show f]
]
]
]
main: center-face layout [
styles styly
backdrop %carlwaves.jpg effect [tile gradcol 0x1 0.0.120]
txt "Playing with progress bars. Note - progress/bar is shared!"
txt "That's why I saved the object first"
r1: progr1
r2: progr2
r3: progr3
r4: progr4
pad 15
button black "Go" [
r1/data: r1/data + 0.05 show r1
r2/data: r2/data + 0.05 show r2
r3/data: r3/data + 0.05 show r3
r4/data: r4/data + 0.05 show r4
]
button black "End" [unview/all]
] none
view main